tests/ECPQ7Tests/EPPTests/update-site/project/GettingStarted.test

--- RCPTT testcase ---
Format-Version: 1.0
Contexts: _ZOi4wZ77EeOm87IlbkWrfQ,_ihvnUC3mEeSwhO5Nwx0hPg,_ih4KMC3mEeSwhO5Nwx0hPg
Element-Name: GettingStarted
Element-Type: testcase
Element-Version: 3.0
External-Reference: 
Id: _lx7aYE_YEeWlOMw7vcjT4A
Runtime-Version: 2.4.2.201905052359
Save-Time: 7/3/19 10:51 AM
Testcase-Type: ecl

------=_.content-0a7243a0-75d3-3d5f-9791-539de0e5b7ac
Content-Type: text/ecl
Entry-Name: .content

// 01 Choose A Domain Model
get-menu -path "File/New/Project..." | click
with [get-window "New Project"] {
    get-tree | select "Examples/EMF Forms/Make it happen: example model"
    get-tree | select "Examples/EMF Forms/Make it happen: example model"
    get-button Finish | click
}

// 01 Choose A Domain Model: verify
get-view "Project Explorer" | get-tree | select "org.eclipse.emf.ecp.makeithappen.model"
get-view "Project Explorer" | get-tree | select "org.eclipse.emf.ecp.makeithappen.model.edit"

// 02 Create A View Model
get-view "Project Explorer" | get-tree | select "org.eclipse.emf.ecp.makeithappen.model/model/task.ecore" 
    | get-menu "EMF Forms/Create View Model Project" | click
with [get-window "New View Model Project"] {
    get-button "Next >" | click
    get-tree | select User
    get-button Finish | click
}

// 02 Create A View Model: verify
get-view "Project Explorer" | get-tree | select "org.eclipse.emf.ecp.makeithappen.model.viewmodel"
get-view "Project Explorer" | get-tree | select "org.eclipse.emf.ecp.makeithappen.model.viewmodel/viewmodels/User.view"

get-view "Project Explorer" | get-tree | select "org.eclipse.emf.ecp.makeithappen.model.viewmodel/plugin.xml" 
    | double-click
with [get-editor "org.eclipse.emf.ecp.makeithappen.model.viewmodel"] {
    get-tab-folder | get-tab-item Extensions | click
    
    get-section "All Extensions" | get-tree 
        | select "org.eclipse.emf.ecp.view.model.provider.xmi.file/viewmodels\\/User.view (file)"
        
    get-section "Extension Element Details" | get-editbox -after [get-link "filePath*:"] | get-property text | equals "viewmodels/User.view" | verify-true
}

// 03 The View Model Editor
with [get-view "Project Explorer" | get-tree] {
    select "org.eclipse.emf.ecp.makeithappen.model.viewmodel/viewmodels/User.view" | double-click
}

// 03 The View Model Editor: verify (default controls)
get-editor "User.view" | get-button "Open Preview" | click
get-view "EMF Forms Preview" | get-button "Clear Sample Data" | click

get-editor "User.view" | get-button "Open Preview" | click
with [get-view "EMF Forms Preview"] {
    with [get-editbox -after [get-label "First Name"]] {
        set-text Markus
        key-type "TRAVERSE_TAB_NEXT"
    }
    with [get-editbox -after [get-label "Last Name*"]] {
        set-text Thort
        set-text Thortz
        set-text Thortze
        set-text Thortzen
        key-type "TRAVERSE_TAB_NEXT"
    }
    get-combo -after [get-label Gender] | select Male
    get-button -after [get-label Active] | check
    get-button "Select Date" | click
}
with [get-window -from "DateTimeControlSWTRenderer$SetBtnSelectionAdapterExtension.setDate()"] {
    get-date-time | set-value "2015/6/3 0:0:0"
    get-button OK | click
}
with [get-view "EMF Forms Preview"] {
    get-date-time | set-value "2015/7/3 12:20:24"
    get-date-time -after [get-label "Time Of Registration"] -index 1 | set-value "2015/6/9 0:59:0"
    get-editbox -after [get-label Weight] | set-text 123
    get-editbox -after [get-label Heigth] | set-text 321
    get-combo -after [get-label Nationality] | select UK
    get-editbox -after [get-label "Date Of Birth"] | click-text
    get-button -after [get-label "Date Of Birth"] | click
}
with [get-window -from "XMLDateControlSWTRenderer$SelectionAdapterExtension.widgetSelected()"] {
    get-date-time | set-value "2015/4/29 0:0:0"
    get-button OK | click
}
with [get-view "EMF Forms Preview"] {
    get-date-time | get-property date | equals "2015/7/3" | verify-true
    get-date-time -after [get-label "Time Of Registration"] -index 1 | get-property time | equals "0:59:0" | verify-true
    get-editbox -after [get-label "Date Of Birth"] | get-property text | equals "Apr 29, 2015" | verify-true
    with [get-editbox -after [get-label "Email*"]] {
        set-text "markus@blubb.com"
    }
}

// 03 The View Model Editor: verify (manual controls)
get-editor "User.view" | get-button "Open Preview" | click
get-view "EMF Forms Preview" | get-button "Clear Sample Data" | click

with [get-editor "User.view" | get-tree] {
    select "User/Control firstName" "User/Control lastName" "User/Control gender" "User/Control active" "User/Control timeOfRegistration" "User/Control weight" "User/Control heigth" "User/Control nationality" "User/Control dateOfBirth" "User/Control email" "User/Control tasks"
    get-menu Delete | click
    select User | get-menu "Generate Controls" | click
}
with [get-window -class WizardDialog] {
	get-table | get-property itemCount | equals 11 | verify-true
    with [get-table] {
        get-item "firstName : EString" | check
        get-item "lastName : EString" | check
        get-item "nationality : Nationality" | check
    }
    get-button Finish | click
}

get-editor "User.view" | get-tree | get-property "getTopItem().getItemCount()" | equals 3 | verify-true
get-editor "User.view" | get-button "Open Preview" | click
with [get-view "EMF Forms Preview"] {
	get-button "Refresh Preview View" | click
    get-control Any -after [get-label "View Editor Preview"] -index 10 | get-property "getChildren().length" | equals 9 
        | verify-true
    get-editbox -after [get-label "Last Name*"] | get-property text | equals "" | verify-true
    with [get-label "" -after [get-label "Last Name*"]] {
        get-property backgroundColor | equals "#FFFFFF" | verify-true
        get-property "image.path" | equals "org.eclipse.emfforms.swt.core/icons/validation_error.png" | verify-true
    }
}
with [get-view "EMF Forms Preview"] {
    with [get-editbox -after [get-label "First Name"]] {
        set-text Regina
        key-type "TRAVERSE_TAB_NEXT"
    }
    with [get-editbox -after [get-label "Last Name*"]] {
        set-text Rasek
    }
    get-combo -after [get-label Nationality] | select Russian
}
with [get-view "EMF Forms Preview" | get-label "" -after [get-label "Last Name*"]] {
    get-property backgroundColor | equals "#FFFFFF" | verify-true
    get-property "getImage()" | equals null | verify-true
}

// 03 The View Model Editor: verify (manual controls reorder)
get-view "EMF Forms Preview" | get-button "Refresh Preview View" | click
with [get-view "EMF Forms Preview" | get-control Any -after [get-label "View Editor Preview"] -index 10] {
    get-property "getChildren().Control[0].getText()" | equals "First Name" | verify-true
    get-property "getChildren().Control[3].getText()" | equals "Last Name*" | verify-true
}
with [get-editor "User.view" | get-tree] {
    select "User/Control lastName"
    get-item "User/Control lastName" | drag-start 66 6
    get-item "User/Control lastName" | drag-enter 88 2 -detail move
    get-item "User/Control lastName" | drag-over 153 0
    get-item "User/Control firstName" | drag-over 202 3 -detail move
    get-item "User/Control lastName" | drag-exit
    get-item "User/Control firstName" | drag-accept 202 3 -detail move
    drag-set-data
    get-item "User/Control firstName" | drop 202 3 -detail move
    drag-end -detail move
}
get-view "EMF Forms Preview" | get-button "Refresh Preview View" | click
with [get-view "EMF Forms Preview" | get-control Any -after [get-label "View Editor Preview"] -index 10] {
    get-property "getChildren().Control[0].getText()" | equals "Last Name*" | verify-true
    get-property "getChildren().Control[3].getText()" | equals "First Name" | verify-true
}

// 04 The First View Model
// ensure neutral state
get-editor "User.view" | get-tree | select User | get-items | foreach {
	select-item
	if [ get-property caption -raw | not-eq "User" ] { get-menu "Delete" | click }
}
get-editor "User.view" | get-tree | get-item User | get-property caption | equals User | verify-true
get-editor "User.view" | get-tree | select User | get-menu "Generate Controls" | click
with [get-window -class WizardDialog] {
    get-button "Select All" | click
    get-button Finish | click
}

proc "drag-onto" [val source] [val target] [val sx 10] [val sy 5] [val tx 10] [val ty 5] {
	select $source
    get-item $source | drag-start 38 10
    get-item $source | drag-enter 55 10 -detail move
    get-item $target | drag-over 116 7 -detail move
    get-item $source | drag-exit
    get-item $target | drag-accept 116 7 -detail move
    drag-set-data
    get-item $target | drop 116 7 -detail move
    drag-end -detail move
}

with [get-editor "User.view"] {
	with [get-tree] {
	    select User | get-menu HorizontalLayout | click
	    select "User/HorizontalLayout" | get-menu VerticalLayout | click
        select "User/HorizontalLayout" | get-menu VerticalLayout | click
        select "User/HorizontalLayout/VerticalLayout"
    }
    get-editbox -after [get-label Name] | set-text Primary
    get-tree | select [get-item "User/HorizontalLayout" | get-item VerticalLayout]
    get-editbox -after [get-label Name] | set-text Secondary
}
with [get-editor "User.view" | get-tree] {
	drag-onto "User/Control firstName" "User/HorizontalLayout/VerticalLayout Primary"
	drag-onto "User/Control lastName" "User/HorizontalLayout/VerticalLayout Primary"
	drag-onto "User/Control nationality" "User/HorizontalLayout/VerticalLayout Primary"
	drag-onto "User/Control gender" "User/HorizontalLayout/VerticalLayout Primary"
	drag-onto "User/Control active" "User/HorizontalLayout/VerticalLayout Primary"
	
	drag-onto "User/Control heig(th|ht)" "User/HorizontalLayout/VerticalLayout Secondary"
	drag-onto "User/Control timeOfRegistration" "User/HorizontalLayout/VerticalLayout Secondary"
	drag-onto "User/Control dateOfBirth" "User/HorizontalLayout/VerticalLayout Secondary"
	drag-onto "User/Control email" "User/HorizontalLayout/VerticalLayout Secondary"
	drag-onto "User/Control weight" "User/HorizontalLayout/VerticalLayout Secondary"
	
	drag-onto "User/HorizontalLayout" "User/Control tasks" -ty 1
}

// 04 The First View Model: verify
get-view "EMF Forms Preview" | get-button "Refresh Preview View" | click
with [get-view "EMF Forms Preview"] {
    get-control Any -after [get-label "View Editor Preview"] -index 11 | get-property "getLayout().numColumns" 
        | equals 2 | verify-true
    get-label Active | get-property caption | equals Active | verify-true
    with [get-control Any -after [get-label Nationality] -index 9] {
        get-property "getChildren().length" | equals 15 | verify-true
    }
}
------=_.content-0a7243a0-75d3-3d5f-9791-539de0e5b7ac--