examples/org.eclipse.etrice.examples.c/model/Features/ActorRefs.room

RoomModel ActorRefs {
	
	LogicalSystem System {
		SubSystemRef main : SubSystemExample
	}
	
	SubSystemClass SubSystemExample {
		ActorRef mainActor1 : ActorClassExample
		ActorRef mainActor2 : ActorClassExampleReplicated
		
		LogicalThread default_thread
	}
	
	ActorClass ActorClassExample {
		Structure {
			ActorRef sender : Sender
			ActorRef receiver : Receiver
			
			Binding receiver.port and sender.port		
		}
	}
	
	ActorClass ActorClassExampleReplicated {
		Structure {
			ActorRef sender[3]: Sender
			ActorRef receiver[3] : Receiver
			
			Binding receiver.port and sender.port
			/* Equivalent to:
			 *  Binding receiver[1].port and sender[1].port
			 *  Binding receiver[2].port and sender[2].port
			 * ....
			 */		
		}
	}
	
	ActorClass Sender {
		Interface {
			conjugated Port port : SimpleProtocol
		}
	}
	
	ActorClass Receiver {
		Interface {
			Port port : SimpleProtocol
		}
	}
	
	ProtocolClass SimpleProtocol {
		incoming {
			Message message1()
		}
	}
}