examples/org.eclipse.emf.parsley.examples.cdo.company.ui.products/src/org/eclipse/emf/parsley/examples/cdo/company/ui/products/module.parsley

import java.util.List
import org.eclipse.emf.ecore.resource.Resource
import org.eclipse.emf.parsley.examples.cdo.company.Category
import org.eclipse.emf.parsley.examples.cdo.company.Company
import org.eclipse.emf.parsley.examples.cdo.company.CompanyGuiceModule
import org.eclipse.emf.parsley.examples.cdo.company.Product
import org.eclipse.emf.parsley.examples.cdo.company.ui.products.ProductsTreeFormView
import org.eclipse.swt.SWT

/* org.eclipse.emf.parsley.examples.cdo.company.ui.products EMF Parsley Dsl Module file */
module org.eclipse.emf.parsley.examples.cdo.company.ui.products extends CompanyGuiceModule{
	
	parts {
		viewpart org.eclipse.emf.parsley.examples.cdo.company.ui.products {
			viewname "Products tree form"
			viewclass ProductsTreeFormView
		}
	}

	bindings {
		value int TreeFormSashStyle -> SWT.HORIZONTAL
		value List<Integer> TreeFormSashWeights -> #[1, 3]
	}
	
	labelProvider{
		image{
			Product -> "product2.png"
			Category -> "category.png"
		}
		text{
			Category -> name
			Product -> "Product: " + name
		}
	}

	viewerContentProvider{
		elements{
			Resource -> {
				if(^contents.size>0){
					val company = (^contents.get(0) as Company)
					company.categories
				}
			}
		}
	}
	
	featuresProvider{
		features{
			Product -> name, description, price, vat
		}
	}

	featureCaptionProvider{
		text{
			Product: vat -> "V.A.T." 
		}
	}	
	
}