org.eclipse.osbp.xtext.action/model/ActionDSL.xcore

@GenModel(fileExtensions="action")
@GenModel(modelName="ActionDSL")
@GenModel(prefix="ActionDSL")
// force bigModel == false
@GenModel(loadInitialization="false")
@GenModel(literalsInterface="true")

@GenModel(copyrightText="Copyright (c) 2011, 2016 - Loetz GmbH&Co.KG (69115 Heidelberg, Germany)
 All rights reserved. This program and the accompanying materials
 are made available under the terms of the Eclipse Public License 2.0 
 which accompanies this distribution, and is available at
 https://www.eclipse.org/legal/epl-2.0/

 SPDX-License-Identifier: EPL-2.0
 
 Contributors:                                                      
    Christophe Loetz (Loetz GmbH&Co.KG) - initial implementation
 
 generated from ActionDSL.xcore

 ")
@GenModel(updateClasspath="false")
@Ecore(nsURI="http://osbp.eclipse.org/xtext/action/ActionDSL")
@Ecore(nsPrefix="actiondsl")
@Ecore(rootPackage="actiondsl")
package org.eclipse.osbp.xtext.action

import org.eclipse.emf.ecore.EObject
import org.eclipse.emf.ecore.InternalEObject
import org.eclipse.osbp.dsl.semantic.common.types.LPackage
import org.eclipse.osbp.xtext.datainterchange.DataInterchange
import org.eclipse.osbp.xtext.functionlibrarydsl.FunctionLibraryActionGroup
import org.eclipse.osbp.xtext.functionlibrarydsl.FunctionLibraryCanExecute
import org.eclipse.osbp.xtext.functionlibrarydsl.FunctionLibraryExecute
import org.eclipse.osbp.xtext.functionlibrarydsl.FunctionLibraryParameter
import org.eclipse.osbp.xtext.messagedsl.MessageCategory
import org.eclipse.osbp.xtext.messagedsl.MessageItem
import org.eclipse.osbp.xtext.oxtype.resource.EcoreUtil3
import org.eclipse.xtext.xtype.XImportSection

class ActionModel{
	contains XImportSection importSection
	contains ActionPackage[] packages
}

type InternalEObject wraps InternalEObject

class ActionLazyResolver {
	op EObject eResolveProxy(InternalEObject proxy) {
		return EcoreUtil3.resolve(proxy, this.eResource().resourceSet);
	}
}

class ActionPackage extends LPackage {
	boolean withouCommandProvider
	contains ActionCommand[] commands
	contains ActionToolbar[] toolbars
}

class ActionBase extends ActionLazyResolver{
	String name
}

class ActionCommand extends ActionBase{
	contains ActionType actionType
	boolean hasKeyBinding
	String keyBinding
	boolean hasDescription
	String description
}

class ActionToolbar extends ActionBase{
	boolean description
	String descriptionValue
	contains ActionToolbarItem[] actions
}

interface ActionToolbarItem extends ActionBase{

}

class ActionButton extends ActionToolbarItem {
	boolean description
	String descriptionValue
	String iconURI
	refers ActionCommand command
}

class ActionSpacer extends ActionToolbarItem {
	boolean stretch //not implement
}

class ActionState extends ActionToolbarItem {
}

interface ActionType extends ActionLazyResolver{
}

class ActionTask extends ActionType {
	TaskActionEnum action
}

class ActionSelectWorkload extends ActionType {
	SelectWorkloadActionEnum action
}

class ActionDialog extends ActionType {
	DialogActionEnum action
}

class ActionReport extends ActionType {
	ReportActionEnum action
}

class ActionChart extends ActionType {
	ChartActionEnum action
}

class ActionWorkflow extends ActionType {
	WorkflowActionEnum action
}

class ActionDatainterchange extends ActionType {
	DatainterchangeActionEnum action
	refers DataInterchange dataRef
	boolean hasfilter
}

class ActionUI extends ActionType {
	UIActionEnum action
}

class ActionTable extends ActionType {
	TableActionEnum action
}

class ActionOrganization extends ActionType {
	OrganizationActionEnum action
}

class ActionFunction extends ActionType {
	refers FunctionLibraryActionGroup actionGroup
	refers FunctionLibraryCanExecute canExecute
	boolean hasExecuteImmediate
	boolean hasExecuteLater
	refers FunctionLibraryExecute executeImmediate
	refers FunctionLibraryExecute executeLater
	boolean hasMessage
	refers MessageCategory messageCategory
	refers MessageItem onFailMessage
	boolean hasSuccessMessage
	refers MessageItem onSuccessMessage
	boolean hasStartedMessage
	refers MessageItem onStartedMessage
}

class ActionParameter extends ActionBase{
	refers FunctionLibraryParameter parameter
}

enum TaskActionEnum{
	TASK_ACTION_CLAIM as 'Claim' = 0
	TASK_ACTION_START as 'Start' = 1
	TASK_ACTION_STOP as 'Stop' = 2
	TASK_ACTION_RELEASE as 'Release' = 3
	TASK_ACTION_SUSPEND as 'Suspend' = 4
	TASK_ACTION_RESUME as 'Resume' = 5
	TASK_ACTION_SKIP as 'Skip' = 6
	TASK_ACTION_COMPLETE as 'Complete' = 7
	TASK_ACTION_DELEGATE as 'Delegate' = 8
	TASK_ACTION_FORWARD as 'Forward' = 9
	TASK_ACTION_FAIL as 'Fail' = 10
	TASK_ACTION_REGISTER as 'Register' = 11
	TASK_ACTION_REMOVE as 'Remove' = 12
	TASK_ACTION_ACTIVATE as 'Activate' = 13
	TASK_ACTION_EXIT as 'Exit' = 14
}

enum SelectWorkloadActionEnum{
	WORKLOAD_SELECT_ACTION_REMOVE_ALL as 'RemoveAll' = 0
	WORKLOAD_SELECT_ACTION_ADD_ALL as 'AddAll' = 1
}

enum DialogActionEnum{
	DIALOG_ACTION_NEW as 'New' = 0
	DIALOG_ACTION_SAVE as 'Save' = 1
	DIALOG_ACTION_DELETE as 'Delete' = 2
	DIALOG_ACTION_CANCEL as 'Cancel' = 3
	DIALOG_ACTION_SAVE_AND_NEW as 'SaveAndNew' = 4
	DIALOG_ACTION_SAVE_AS_NEW as 'SaveAsNew' = 5
}

enum ReportActionEnum{
	REPORT_ACTION_PRINT_ON_SERVER_PDF as 'PrintOnServer' = 0
	REPORT_ACTION_DOWNLOAD_PDF as 'ReportDownload' = 1
}

enum ChartActionEnum{
	CHART_ACTION_DOWNLOAD as 'ChartDownload'
}

enum WorkflowActionEnum{
	WORKFLOW_ACTION_START as 'Start'
}

enum DatainterchangeActionEnum {
	DATAINTERCHANGE_ACTION_IMPORT as 'Import'
	DATAINTERCHANGE_ACTION_EXPORT as 'Export'
}	 

enum Operator{
	equals as '='
	notequals as '!='
	greaterthen as '>'
	greaterthenorequalto as '>='
	lessthen as '<'
	lessthenorequalto as '<='
	isnull as 'isnull'
	isnotnull as 'isnotnull'
}

enum Junction{
	and as 'and'
	or as 'or'
}

enum UIActionEnum {
	NEXT_PART as 'NextPart'
	PREVIOUS_PART as 'PreviousPart'
	NEXT_PERSPECTIVE as 'NextPerspective'
	PREVIOUS_PERSPECTIVE as 'PreviousPerspective'
	DATABASE_INFO as 'Info'
	MDX_QUERY as 'MDXQuery'
}

enum TableActionEnum {
	EXPORT_EXCEL as 'ExportExcel'
	EXPORT_CSV as 'ExportCsv'
	EXPORT_PDF as 'ExportPDF'
}

enum OrganizationActionEnum {
	ZOOM as 'Zoom'
	ZOOM_IN as 'ZoomIn'
	ZOOM_OUT as 'ZoomOut'
	ZOOM_ACTUAL as 'ZoomActual'
	SAVE as 'Save'
	PRINT as 'Print'
	POSTER_PRINT as 'PosterPrint'
}