org.eclipse.osbp.xtext.menu/src/org/eclipse/osbp/xtext/menu/GenerateMenuDsl.mwe2

/* 
 * Copyright (c) 2014,2016 Loetz GmbH&Co.KG (Heidelberg)
 * All rights reserved. This program and the accompanying materials 
 * are made available under the terms of the Eclipse Public License v1.0 
 * which accompanies this distribution, and is available at 
 * http{//www.eclipse.org/legal/epl-v10.html 
 *
 * Contributors:  
 *		Loetz GmbH&Co.KG - Initial implementation 
 */
 module org.eclipse.osbp.xtext.menu.GenerateMenuDsl

import org.eclipse.emf.mwe.utils.*
import org.eclipse.xtext.xtext.generator.*
import org.eclipse.xtext.xtext.generator.model.project.*

var rootPath = ".."

Workflow {

	component = XtextGenerator {
		configuration = {
			project = StandardProjectConfig {
				baseName = "org.eclipse.osbp.xtext.menu"
				rootPath = rootPath
				genericIde = {
					enabled = true
					name = "org.eclipse.osbp.xtext.menu.ide"
				}
				runtimeTest = {
					enabled = true
				}
				eclipsePlugin = {
					enabled = true
				}
				eclipsePluginTest = {
					enabled = false
				}
				createEclipseMetaData = true
			}
			code = {
				encoding = "UTF-8"
				lineDelimiter = "\n"
				fileHeader = "/*\n * generated by Xtext \${version}\n */"
			}
		}

		language = StandardLanguage {
			name = "org.eclipse.osbp.xtext.menu.MenuDsl"
			fileExtensions = "menu"
			
			referencedResource = "platform:/resource/org.eclipse.osbp.xtext.menu/model/MenuDsl.xcore"
			
			referencedResource = "platform:/resource/org.eclipse.osbp.xtext.oxtype/model/OXtype.ecore"
			referencedResource = "platform:/resource/org.eclipse.osbp.xtext.oxtype/model/OXtype.genmodel"
			referencedResource = "platform:/resource/org.eclipse.osbp.dsl.common.xtext/model/types.xcore"
			referencedResource = "platform:/resource/org.eclipse.osbp.dsl.dto.xtext/model/dto.xcore"
			referencedResource = "platform:/resource/org.eclipse.osbp.xtext.perspective/model/PerspectiveDsl.xcore"
			referencedResource = "platform:/resource/org.eclipse.osbp.xtext.blip/model/BlipDSL.xcore"
			referencedResource = "platform:/resource/org.eclipse.osbp.xtext.table/model/TableDSL.xcore"
			referencedResource = "platform:/resource/org.eclipse.osbp.xtext.dialogdsl/model/DialogDSL.xcore"

			generateXtendStubs = false
			
			serializer = {
				generateStub = false
			}
			validator = {
			// composedCheck = "org.eclipse.xtext.validation.NamesAreUniqueValidator"
			}

			generator = {
				generateStub = false
				generateJavaMain = false
				generateXtendStub = false
			}

		}
	}
}