releng/org.eclipse.qvtd.build/src/org/eclipse/qvtd/build/mwe2/GenerateQVTdScheduleModels.mwe2

/*******************************************************************************
 * Copyright (c) 2010 Willink Transformations and others.
 * All rights reserved. This program and the accompanying materials
 * are made available under the terms of the Eclipse Public License v1.0
 * which accompanies this distribution, and is available at
 * http://www.eclipse.org/legal/epl-v10.html
 *
 * Contributors:
 *     E.D.Willink - initial API and implementation
 *
 * Run As->MWE2 Workflow to regenerate the Xtest CST models.
 *******************************************************************************/
module GenerateQVTdScheduleModels

import org.eclipse.qvtd.build.modelspecs.*
import org.eclipse.qvtd.build.utilities.*
import org.eclipse.qvtd.build.xtend.*
import org.eclipse.ocl.examples.build.utilities.*
import org.eclipse.ocl.examples.build.xtend.*
import org.eclipse.emf.mwe.utils.*
import org.eclipse.emf.mwe.utils.*
import org.eclipse.emf.ecore.resource.impl.*

/**
 *	Generate the Schedule Model used by the QVT scheduling.
 */
Workflow {
	bean = ResourceSetImpl : resourceSet {}
    bean = StandaloneSetup { resourceSet = resourceSet
    	platformUri = ".."
    	scanClassPath = true
    }
    bean = EcoreGenModelSetup { resourceSet = resourceSet }

    component = GenerateModel { resourceSet = resourceSet skipOnErrors = true
    	genModel = "/org.eclipse.qvtd.pivot.schedule/model/Schedule.genmodel" 	
    }
    component = GenerateScheduleVisitors { resourceSet = resourceSet
    	projectName = "org.eclipse.qvtd.pivot.schedule"
    	projectPrefix = "ScheduleModel"
    	superProjectName = ""
    	genModelFile = "model/Schedule.genmodel"
    	javaFolder = "emf-gen"
    	modelPackageName = "org.eclipse.qvtd.pivot.schedule"
    	visitorPackageName = "org.eclipse.qvtd.pivot.schedule.util"
    	visitorClassName = "ScheduleVisitor"
    	visitablePackageName = "org.eclipse.qvtd.pivot.schedule"
    	visitableClassName= "ScheduleElement"
    }
	component = ConvertToUnixLineEndings {
		directory = "org.eclipse.qvtd.pivot.schedule/emf-gen"
	}
}