releng/org.eclipse.qvtd.build/src/org/eclipse/qvtd/build/mwe2/GenerateQVTdLibraryModels.mwe2

/*******************************************************************************
 * Copyright (c) 2015 Willink Transformations and others.
 * All rights reserved. This program and the accompanying materials
 * are made available under the terms of the Eclipse Public License v2.0
 * which accompanies this distribution, and is available at
 * http://www.eclipse.org/legal/epl-v20.html
 *
 * Contributors:
 *   E.D.Willink - initial API and implementation
 *
 * Run As->MWE2 Workflow to regenerate the pivot model.
 *******************************************************************************/
module GenerateQVTdLibraryModels

import org.eclipse.ocl.examples.build.utilities.*
import org.eclipse.ocl.examples.build.xtend.*
import org.eclipse.emf.mwe.utils.*
import org.eclipse.emf.mwe.utils.*
import org.eclipse.emf.ecore.resource.impl.*

/**
 *	Generate the QVTbase and QVTimperative Library Models.
 */
Workflow {
	bean = ResourceSetImpl : libResourceSet {}
    bean = StandaloneSetup { resourceSet = libResourceSet
    	platformUri = "../../plugins"
//    	scanClassPath = true
    }
	bean = ProjectMapSetup { resourceSet = libResourceSet }
    bean = EcoreGenModelSetup { resourceSet = libResourceSet }
  	component = OCLInstanceSetup : libInstanceSetup { resourceSet = libResourceSet }
    component = GenerateOCLstdlibXtend { oclInstanceSetup = libInstanceSetup
    	projectName = "org.eclipse.qvtd.runtime"
    	modelFile = "model/QVTruntimeLibrary.oclstdlib"
    	uri = "http://www.eclipse.org/qvt/2019/QVTruntimeLibrary"
    	ecoreFile = "/org.eclipse.qvtd.runtime/model-gen/QVTruntimeLibrary.ecore"
    	javaFolder = "/org.eclipse.qvtd.runtime/emf-gen"
    	javaPackageName = "org.eclipse.qvtd.runtime.model"
    	javaClassName = "QVTruntimeLibrary"
    	generatedClassNameMap = {
    		from = "http://www.eclipse.org/ocl/2015/Pivot"
    		to = "org.eclipse.ocl.pivot.model.OCLmetamodel"
    	}
    	generatedClassNameMap = {
    		from = "http://www.eclipse.org/ocl/2015/Library"
    		to = "org.eclipse.ocl.pivot.model.OCLstdlib"
    	}
    	generatedClassNameMap = {
    		from = "http://www.eclipse.org/qvt/2015/QVTbase"
    		to = "org.eclipse.qvtd.pivot.qvtbase.model.QVTbaseMetamodel"
    	}
    	excludedEClassifierName = "PseudoOperations"
    //	excludedEClassifierName = "Extent"
    //	excludedEClassifierName = "Model"
    //	excludedEClassifierName = "Transformation"
    	useOCLstdlib = true
    	isASLibrary = false
    }
	component = OCLInstanceSuspend { oclInstanceSetup = libInstanceSetup }
	bean = ResourceSetImpl : qvtbResourceSet {}
	bean = ProjectMapSetup { resourceSet = qvtbResourceSet }
    bean = EcoreGenModelSetup { resourceSet = qvtbResourceSet }
  	component = OCLInstanceSetup : qvtbInstanceSetup { resourceSet = qvtbResourceSet }
    component = GenerateModel { oclInstanceSetup = qvtbInstanceSetup skipOnErrors = true
    	genModel = "/org.eclipse.qvtd.runtime/model/QVTruntimeLibrary.genmodel"
    }
    component = Model2tablesGenerator { oclInstanceSetup = qvtbInstanceSetup
    	genModelFile = "/org.eclipse.qvtd.runtime/model/QVTruntimeLibrary.genmodel"
    	genOCLstdlib = false // true
    }
	component = OCLInstanceDispose { oclInstanceSetup = qvtbInstanceSetup }
	component = OCLInstanceResume { oclInstanceSetup = libInstanceSetup }
    component = GenerateOCLstdlibXtend { oclInstanceSetup = libInstanceSetup
    	projectName = "org.eclipse.qvtd.pivot.qvtimperative"
    	modelFile = "model/QVTimperativeLibrary.oclstdlib"
    	uri = "http://www.eclipse.org/qvt/2016/QVTimperativeLibrary"
    	ecoreFile = "/org.eclipse.qvtd.pivot.qvtimperative/model-gen/QVTimperativeLibrary.ecore"
    	javaFolder = "/org.eclipse.qvtd.pivot.qvtimperative/emf-gen"
    	javaPackageName = "org.eclipse.qvtd.pivot.qvtimperative.model"
    	javaClassName = "QVTimperativeLibrary"
    	generatedClassNameMap = {
    		from = "http://www.eclipse.org/ocl/2015/Pivot"
    		to = "org.eclipse.ocl.pivot.model.OCLmetamodel"
    	}
    	generatedClassNameMap = {
    		from = "http://www.eclipse.org/ocl/2015/Library"
    		to = "org.eclipse.ocl.pivot.model.OCLstdlib"
    	}
    	generatedClassNameMap = {
    		from = "http://www.eclipse.org/qvt/2016/QVTimperative"
    		to = "org.eclipse.qvtd.pivot.qvtimperative.model.QVTimperativeMetamodel"
    	}
    	excludedEClassifierName = "PseudoOperations"
    	excludedEClassifierName = "Extent"
    	excludedEClassifierName = "Model"
    	excludedEClassifierName = "Transformation"
    	isASLibrary = false
    }
	component = OCLInstanceDispose { oclInstanceSetup = libInstanceSetup }
	bean = ResourceSetImpl : qvtiResourceSet {}
	bean = ProjectMapSetup { resourceSet = qvtiResourceSet }
    bean = EcoreGenModelSetup { resourceSet = qvtiResourceSet }
  	component = OCLInstanceSetup : qvtiInstanceSetup { resourceSet = qvtiResourceSet }
    component = GenerateModel { oclInstanceSetup = qvtiInstanceSetup skipOnErrors = true
    	genModel = "/org.eclipse.qvtd.pivot.qvtimperative/model/QVTimperativeLibrary.genmodel"
    }
    component = Model2tablesGenerator { oclInstanceSetup = qvtiInstanceSetup
    	genModelFile = "/org.eclipse.qvtd.pivot.qvtimperative/model/QVTimperativeLibrary.genmodel"
    	genOCLstdlib = true
    }
	component = OCLInstanceDispose { oclInstanceSetup = qvtiInstanceSetup }
}