examples/org.eclipse.ocl.examples.autogen/src/org/eclipse/ocl/examples/autogen/SubGenerateAutoASModel.mwe2

/*******************************************************************************
 * Copyright (c) 2013, 2015 Willink Transformations and others.
 * All rights reserved. This program and the accompanying materials
 * are made available under the terms of the Eclipse Public License v2.0
 * which accompanies this distribution, and is available at
 * http://www.eclipse.org/legal/epl-v20.html
 *
 * Contributors:
 *     E.D.Willink - initial API and implementation
 *     Adolfo Sanchez-Barbudo Herrera (University of York) - Lookup Environment/Visitor
 *
 *******************************************************************************/
module SubGenerateAutoASModel

import org.eclipse.ocl.examples.build.utilities.GenerateModel
import org.eclipse.ocl.examples.build.xtend.GenerateCSVisitors
import org.eclipse.ocl.examples.autogen.xtend.GenerateAutoLookupInfrastructureXtend 
import org.eclipse.emf.ecore.resource.ResourceSet

/**
 * A ResourceSet that may be shared by workflow components.
 */
var ResourceSet resourceSet

/**
 * The name of the project hosting the generated models; e.g. "org.eclipse.ocl.xtext.essentialocl"
 */
var projectName

/**
 * The path inside the ${projectName} to the Complete OCL file which contains the name resolution description; 
 * (e.g. "model/NameResolution.ocl"). 
 */
var lookupFilePath

/**
 * The project-relative genmodel file; e.g.: "model/EssentialOCLCS.genmodel".
 */
var genModelFile

/**
 * The name of the inherited project hosting the generated models; e.g. "org.eclipse.ocl.xtext.essentialocl"; "" for a base project.
 */
var superProjectName = ""

/**
 * (Optional) The project-relative genmodel file of the inherited project; default: "".
 */
var superGenModelFile = ""


/**
 * (Optional) The name of the base project hosting the generated models; e.g. "org.eclipse.ocl.xtext.base"; "" for a base project; default: ""
 */
var baseProjectName = ""
 
/**
 * (Optional) The project-relative genmodel file of the base project; default: "".
 */
var baseGenModelFile = ""

/**
 * (Optional) The package for generated lookup artefacts; default: "${modelJavaPackageName}.lookup".
 */
var lookupPackageName = ""

/**
 * (Optional) The super package for generated lookup artefacts; default: "${superModelJavaPackageName}.lookup".
 */
var superlookupPackageName = "" // By passing a blank the Xtend component will compute the default


/**
 * (Optional) The base package for generated lookup artefacts; default: "${baseModelJavaPackageName}.lookup".
 */
var baselookupPackageName = "" // By passing a blank the Xtend component will compute the default

/**
 *	Generate a Concrete Syntax Model and its visitors as used by the Xtext editors.
 */
Workflow {
    component = GenerateAutoLookupInfrastructureXtend { resourceSet = resourceSet skipOnErrors = true
    	projectName = projectName
    	genModelFile = genModelFile
    	superProjectName = superProjectName
    	superGenModelFile = superGenModelFile
    	baseProjectName = baseProjectName
    	baseGenModelFile = baseGenModelFile
    	lookupFilePath = lookupFilePath
    	lookupPackageName = lookupPackageName
    	superLookupPackageName = superlookupPackageName
    	baseLookupPackageName = baselookupPackageName
    }
}