org.eclipse.osbp.xtext.signal.ui/src/org/eclipse/osbp/xtext/signal/ui/contentassist/SignalDSLProposalProvider.xtend

/**
 *                                                                            
 *  Copyright (c) 2011, 2018 - Loetz GmbH&Co.KG (69115 Heidelberg, Germany) 
 *                                                                            
 *  All rights reserved. This program and the accompanying materials           
 *  are made available under the terms of the Eclipse Public License 2.0        
 *  which accompanies this distribution, and is available at                  
 *  https://www.eclipse.org/legal/epl-2.0/                                 
 *                                 
 *  SPDX-License-Identifier: EPL-2.0                                 
 *                                                                            
 *  Contributors:                                                      
 * 	   Christophe Loetz (Loetz GmbH&Co.KG) - initial implementation
 * 
 * generated by Xtext 2.11.0
 * 
 */

package org.eclipse.osbp.xtext.signal.ui.contentassist

import com.google.inject.Inject
import java.net.MalformedURLException
import java.net.URL
import java.nio.file.Paths
import org.eclipse.emf.common.util.EList
import org.eclipse.emf.ecore.EObject
import org.eclipse.jface.viewers.StyledString
import org.eclipse.osbp.xtext.basic.ui.contentassist.BasicDSLProposalProviderHelper
import org.eclipse.osbp.xtext.signal.SignalDatainterchange
import org.eclipse.osbp.xtext.signal.SignalExecutionTypeEnum
import org.eclipse.osbp.xtext.signal.SignalScheduler
import org.eclipse.osbp.xtext.signal.WatcherWithFileMask
import org.eclipse.osbp.xtext.signal.WatcherWithFileName
import org.eclipse.osbp.xtext.signal.ui.SignalDSLDocumentationTranslator
import org.eclipse.swt.widgets.DirectoryDialog
import org.eclipse.wb.internal.core.nls.ui.ChooseLocaleDialog
import org.eclipse.xtext.Keyword
import org.eclipse.xtext.RuleCall
import org.eclipse.xtext.common.ui.contentassist.TerminalsProposalProvider
import org.eclipse.xtext.ui.editor.contentassist.ConfigurableCompletionProposal
import org.eclipse.xtext.ui.editor.contentassist.ContentAssistContext
import org.eclipse.xtext.ui.editor.contentassist.ICompletionProposalAcceptor
import org.eclipse.xtext.ui.editor.contentassist.ReplacementTextApplier
import org.eclipse.osbp.xtext.signal.SignalWatcher

class LocaleTextApplier extends ReplacementTextApplier {
	var ContentAssistContext context

	def setContext(ContentAssistContext context) {
		this.context = context
	}

	override getActualReplacementString(ConfigurableCompletionProposal proposal) {
		var display = context.getViewer().getTextWidget().getDisplay();
		var localeDialog = new ChooseLocaleDialog(display.getActiveShell());
		localeDialog.open();
		return "\"".concat(localeDialog.selectedLocale.toString).concat("\"");
	}
}

class DirectoryNameTextApplier extends ReplacementTextApplier {
	var ContentAssistContext context

	def setContext(ContentAssistContext context) {
		this.context = context
	}

	// this will inject a directory dialog when selecting the dialog picker proposal 
	override getActualReplacementString(ConfigurableCompletionProposal proposal) {
		var display = context.getViewer().getTextWidget().getDisplay();
		var dirDialog = new DirectoryDialog(display.getActiveShell());
		var dirName = dirDialog.open();
		if (dirName !== null) {
			dirName = dirName.replace("\\", "/")
		} else {
			dirName = "Directory"
		}
		return "\"".concat(dirName).concat("\"");
	}
}

class SignalDSLProposalProvider extends AbstractSignalDSLProposalProvider {

	@Inject TerminalsProposalProvider provider
	@Inject BasicDSLProposalProviderHelper providerHelper

	override protected StyledString getKeywordDisplayString(Keyword keyword) {
		return BasicDSLProposalProviderHelper.getKeywordDisplayString(keyword,
			SignalDSLDocumentationTranslator.instance())
	}

	/**
	 * This override will enable 1 length non letter characters as keyword.
	 */
	override protected boolean isKeywordWorthyToPropose(Keyword keyword) {
		return true
	}

	override complete_QualifiedName(EObject model, RuleCall ruleCall, ContentAssistContext context,
		ICompletionProposalAcceptor acceptor) {
		providerHelper.complete_PackageName(model, ruleCall, context, acceptor, this)
	}

	def directoryPickerProposal(EObject model, ContentAssistContext context, ICompletionProposalAcceptor acceptor) {
		var dirName = createCompletionProposal("Select directory...", context) as ConfigurableCompletionProposal
		if (dirName !== null) {
			var applier = new DirectoryNameTextApplier()
			applier.setContext(context)
			dirName.setTextApplier = applier
		}
		acceptor.accept(dirName)
	}

	/**
	 * This method decided which proposals will be valid. 
	 */
	override protected boolean isValidProposal(String proposal, String prefix, ContentAssistContext context) {
		var result = super.isValidProposal(proposal, prefix, context)
	
		if (context.currentModel instanceof SignalWatcher) {
			result = isValidProposalForSignalWatcherType(proposal, prefix, (context.currentModel as SignalWatcher), result)
		}
		else if(context.currentModel instanceof SignalDatainterchange){
			result = isValidProposalSignalDatainterchange(proposal, prefix, (context.currentModel as SignalDatainterchange), result)
		}
		return result
	}
	
	def isValidProposalSignalDatainterchange(String proposal, String prefix, SignalDatainterchange interchange,
		boolean result) {
			
		if (proposal.equals("applyon") && interchange !== null) {
			if(interchange.eContainer instanceof WatcherWithFileMask){
				return false
			}
			else if(interchange.eContainer instanceof WatcherWithFileName){
				var watcher = (interchange.eContainer as WatcherWithFileName)
				if(watcher.interchanges.size > 1 ){					
					if(watcher.interchanges.basedInterchangeDefined){
						return false
					}
				}				
			}
			else if(interchange.eContainer instanceof SignalScheduler){
				return false
			}
		}
		return result
		
	}
	
	def private boolean isValidProposalForSignalWatcherType(String proposal, String prefix, SignalWatcher signal,
		boolean result) {
		var watcher = signal.definition
		if (watcher !== null) {
			// if the data block has not been defined yet
			if(watcher instanceof WatcherWithFileMask){
				if (proposal.equals("applyon")) {
					return false
				}
			}
			else if(watcher instanceof WatcherWithFileName){
				if(watcher.interchanges.size < 1 && (proposal.equals(SignalExecutionTypeEnum.NOSEQ.literal) || proposal.equals(SignalExecutionTypeEnum.SEQ.literal))){					
					return false
				}
			}
		}
		return result
	}
	
	def boolean basedInterchangeDefined(EList<SignalDatainterchange> interchanges){
		for(unit : interchanges){
			if(unit.baseinterchange){
				return true
			}
		}
		return false
	}
	
	
	def getDirectoryURL(String directory) {
	    try {
			return new URL(directory);
		} catch (MalformedURLException e1) {
			if(e1.getMessage().startsWith("unknown protocol") || e1.getMessage().startsWith("no protocol")) {
				try {
					return Paths.get(directory).toUri().toURL();
				} catch (MalformedURLException e2) {
					return null					
				}
			}
		}
		return null
	}

	// ------------------------ delegates to TerminalsProposalProvider -----------------
	override public void complete_INT(EObject model, RuleCall ruleCall, ContentAssistContext context,
		ICompletionProposalAcceptor acceptor) {
		provider.complete_INT(model, ruleCall, context, acceptor)
	}

	override public void complete_TRANSLATABLEID(EObject model, RuleCall ruleCall, ContentAssistContext context,
		ICompletionProposalAcceptor acceptor) {
		provider.complete_ID(model, ruleCall, context, acceptor)
	}

	override public void complete_TRANSLATABLESTRING(EObject model, RuleCall ruleCall, ContentAssistContext context,
		ICompletionProposalAcceptor acceptor) {
		provider.complete_STRING(model, ruleCall, context, acceptor)
	}

	override public void complete_STRING(EObject model, RuleCall ruleCall, ContentAssistContext context,
		ICompletionProposalAcceptor acceptor) {
		provider.complete_STRING(model, ruleCall, context, acceptor)
	}

}